Робота в Adobe AIR з іконкою в треї

Вивчаючи AIR від Adobe вирішив написати невеличку програмку для своїх потреб. Мені необхідно було зробити так, щоб вона могла ховатися в трей при закритті головного вікна, або його мінімізації. Виявилось що в AIR це досить не тривіальна задача. Далі невеличкий приклад моєї реалізації роботи з треєм.
Створюємо змінну для роботи з системним треєм:

private var sysTrayIcon:SystemTrayIcon = NativeApplication.nativeApplication.icon as SystemTrayIcon;

Далі необхідно створити змінні самого меню і завантажувача малюнка:

private var trayIconMenu:NativeMenu = new NativeMenu();
private var trayIconMenuShow:NativeMenuItem = trayIconMenu.addItem(new NativeMenuItem("Show"));
private var trayIconMenuExit:NativeMenuItem = trayIconMenu.addItem(new NativeMenuItem("Exit"));
private var iconLoader:Loader = new Loader();

У функції яка викликається відразу після того, як створилося вікно (реакція на подію windowComplete) реалізуються механізми взаємодії з системним треєм:

public function Init():void {
 // Перевіряємо чи підтримується робота з системним треєм
 if (NativeApplication.supportsSystemTrayIcon)
 {
     // Налаштовуємо реакцію на шиглик по іконці в треї: виклик clickTrayIconHandler()
     NativeApplication.nativeApplication.icon.addEventListener(MouseEvent.CLICK, clickTrayIconHandler);

     // Налаштовуємо реакцію на завершення завантаження малюнку
     iconLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, function (event:Event):void {
         // Встановлюємо завантажений малюнок у трей
         NativeApplication.nativeApplication.icon.bitmaps = new Array(event.target.content.bitmapData);
     });
  
      // Підказка, що відображається при наведенні миші на іконку в треї
     sysTrayIcon.tooltip = "Systrayicon example";
 
     // Налаштовуємо реакцію на вибір пункту меню Exit у меню
     trayIconMenuExit.addEventListener(Event.SELECT, function (event:Event):void {
         NativeApplication.nativeApplication.icon.bitmaps = [];
         NativeApplication.nativeApplication.exit();    
     });
 
     // Налаштовуємо реакцію на мінімізацію вікна: виклик minimizeHandler()
     stage.nativeWindow.addEventListener(NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING, minimizeHandler);
 
     // Налаштовуємо реакцію на вибір пункту меню Show у меню
     trayIconMenuShow.addEventListener(Event.SELECT, clickTrayIconHandler);
 
     // Встановлюємо меню
     sysTrayIcon.menu = trayIconMenu;
 }
}

Функція-реакція на закриття вікна:

// Реакція на закриття вікна        
protected function closingHandler(event:Event):void
{
 // Забороняємо стандартну реакцію
 event.preventDefault();

 // Ховаємо вікно
 this.visible = false;

 // Завантажуємо і відображаємо іконку в треї
 iconLoader.load(new URLRequest("images/systrayicon.png"));
}

Функція-реакція на щиглик по іконці в треї:

// Реакція на щиглик по іконці в треї, або вибір пункту меню Show
protected function clickTrayIconHandler(event:Event):void
{
 // Прибираємо іконку з трею
 NativeApplication.nativeApplication.icon.bitmaps = [];

 // Відображаємо вікно
 this.visible = true;

 // Переводимо фокус на вікно
 this.activate();
}

Функція-реакція на мінімізацію вікна:

// Реакція на мінімізацію вікна
protected function minimizeHandler(event:Event):void
{
 // Перевіряємо, чи дійсно ми мінімізуємо вікно
 if ((event as NativeWindowDisplayStateEvent).afterDisplayState == NativeWindowDisplayState.MINIMIZED)
 {
     // Забороняємо стандартну реакцію
     (event as NativeWindowDisplayStateEvent).preventDefault();
 
     // Ховаємо вікно
     this.visible = false;
 
     // Завантажуємо і відображаємо іконку в треї
     iconLoader.load(new URLRequest("images/systrayicon.png"));
 }
}

Завантажити вихідні коди проекту.